Коднянко В.А.
Программирование на языке Object Pascal в среде Delphi


17. Файлы

Файлом называется область данных на внешнем носителе – жестком диске, дискете и пр. Всякий файл имеет имя, представляющее собой строку символов. Различают обычное имя (или просто имя) и полное имя. Под полным именем понимается абсолютный адрес файла, состоящий из пути и имени файла. Например, строка 'C:\Program Files\Folder1\Students.dat' является полным именем. Оно состоит из пути 'C:\Program Files\Folder1' к файлу и собственно имени файла 'Students.dat'. Это означает, что файл 'Students.dat' расположен на диске C в папке (директории) Program Files непосредственно в подпапке (субдиректории) Folder1.

Ранее упоминалось, что в языке Object Pascal существует три типа файлов:

<имя> = TextFile; {текстовые файлы}

<имя> = File; {файлы без типа}

<имя> = File of <тип даных>; {файлы с типом}

17.1. Файловая переменная

Для того чтобы получить доступ к файлу, его необходимо сначала открыть. Открытие файла выполняется посредством связывания файла с особой переменной, называемой файловой переменной. Именно файловая переменная и характеризует тип файла. Связывание файла с файловой переменной еще не означает открытия этого файла. Открытие файла производится специальными процедурами, о которых будет упомянуто ниже.

Связывание файла с файловой переменной производится с помощью стандартной процедуры AssignFile, которая имеет заголовок:

AssignFile(<файловая переменная >, <имя файла>);

Например, фрагмент

Var

f1: TextFile;
FullPath: String[60];
…
FullPath:= 'a:\a1.res';
AssignFile(f1, FullPath);

cодержит объявление файловой переменной f1 текстового типа и строки FullPath, которые затем используются в исполнительной части для указания полного имени файла и связывания его с файловой переменной f1.

17.2. Текстовые файлы

Текстовой файл – это последовательность символьных строк перемен-ной длины. Всякая строка завершается маркером конца строки, всякий текстовой файл завершается маркером конца файла. Такие файлы можно обрабатывать только последовательно. Один и тот же текстовой файл не может быть открыт одновременно для ввода и вывода. Файловая переменная этого файла имеет тип TextFile или просто Text.

Для текстовых файлов есть две стандартные файловые переменные – Input и Output, которые не нужно объявлять отдельно.

17.2.1. Процедуры и функции для работы с текстовым файлом

  1. Procedure AssignFile(f: TextFile; FileName: String);

    2. Связывает файловую переменную f с дисковым файлом FileName.

  2. Procedure Append(f: TextFile);

    3. Открывает существующий файл для добавления строк в конец файла. При отсутствии файла возникает ошибка ввода/вывода.
  3. Procedure Rewrite(f: TextFile);

    4. Создает новый файл и открывает его для вывода. Если файл существует, то он уничтожается и создается как новый. Когда новый текстовой файл закрывается, к нему автоматически добавляется маркер конца файла.

  4. Procedure Reset(f: TextFile);

    5. Открывает существующий файл для чтения и устанавливает указатель на первую строку файла. При его отсутствии возникает ошибка ввода/вывода.

  5. Procedure Read( f: TextFile[; v1, v2, …,vN]);

    6. Читает данные из файла и заносит их в переменные v1, v2, …, vN. Переменные могут иметь символьный, строчный или арифметические типы.
  6. Procedure Readln( f: TextFile[; v1, v2, …,vN]);

    7. Читает данные из файла целыми строками и заносит их в переменные v1, v2, …, vN. Если список переменных пуст, то происходит перемещение указателя на следующую строку.
  7. Procedure Write( f: TextFile[; v1, v2, …,vN]);

    8. Записывает данные из переменных v1, v2, …, vN в файл в символьном виде.

  8. Procedure SetTextBuf ( f: TextFile; Var Buf[; Size: Integer]);

    9. Устанавливает буфер чтения текстового файла. Процедура должна быть вызвана после AssignFile, но до первого вызова процедур чтения. Буфер используется для чтения больших фрагментов файла, включая символы конца строк. Если размер буфера не указан, то по умолчанию он принимается равным 128.

  9. Procedure CloseFile( f: TextFile);

    10. Закрывает текстовой файл.

  10. Procedure Flush( f: TextFile);

    11. Выводит содержимое внутреннего буфера в файл.

  11. Function Eof( f: TextFile): boolean;

    12. Возвращает True, если достигнут конец файла.
  12. Function Eoln( f: TextFile): boolean;

    13. Возвращает True, если достигнут конец текущей строки.
  13. Function SeekEof( f: TextFile): boolean;

    14. Возвращает статус конца файла.
  14. Function SeekEoln( f: TextFile): boolean;

Возвращает статус конца строки.

Пример:

Var
F1, F2: TextFile;
Ch: Char;
St: String[255];
Buf: array[1..4096] of Char; { текстовой буфер размером 4K}

begin
AssignFile(F1, 'T1.TXT');
SetTextBuf(F1, Buf); { большой буфер для ускорения чтения}
Reset(F1); {F1 открыт для чтения}
AssignFile(F2, 'WOOF.DOG');
Rewrite(F2); {F2 создан как новый для вывода }

while not Eof(F1) do {пока не достигнут конец файла – выполнять}
begin
Read(F1, Ch); {читает один символ из файла F1}
Write(F2, Ch); {пишет один символ в файл F2}
end;

CloseFile(F1); {файл F1 закрыт}
CloseFile(F2); {файл F2 закрыт}
Reset(F1); {F1 снова открыт для чтения}
Rewrite(F2); {F2 снова создан для вывода }

while not Eof(F1) do {пока не достигнут конец файла – выполнять}
begin
Readln(F1, St); {читает строку из файла F1}
Write(F2, St); {пишет строку в файл F2}
end;

CloseFile(F1); {файл F1 закрыт}
CloseFile(F2); {файл F2 закрыт}
end;

Приведенный фрагмент модуля является демонстрационным и предназначен для копирования файла 'T1.TXT' в файл 'WOOF.DOG' . В первом цикле While – do копирование ведется посимвольно, во втором цикле – построчно.

Пример процедуры, записывающей в конец текстового файла строку символов:

Procedure AddStrToTextFile(nF, St:String);
Var f: Text;

Begin
AssignFile(f, nF);

If not FileExists(nF) then Rewrite(f) {не существует, создать и открыть}
Else {иначе}
Begin
Reset(f); {существует, открыть }
While not Eof(f) do Readln(f); {передвинуть указатель в конец файла}
End;

Writeln(f, St); {записать строку }
CloseFile(f); {закрыть файл}
End;

К процедуре можно обратиться, например, так:

Var

S1: String[58];
S2: String[189];
…
AddStrToTextFile('c:\Files\ring.txt', 'Строка символов');
AddStrToTextFile('ring.txt', S1);
AddStrToTextFile('ring.txt', S2);

17.3. Файлы с типом

Файл состоит из любых однотипных компонент. Доступ к данным осуществляется через файловую переменную. В отличие от текстового файла в таком файле допустим прямой доступ к любой записи, причем в рамках открытого файла допустимо как записывать, так и читать записи.

Примеры объявления файловой переменной для файлов с типом:

Var
F1: File of String[45];
F2: File of Real;
F3: File of tRecord24;

После каждого чтения или вывода записи указатель автоматически устанавливается на следующую запись.

17.3.1. Процедуры и функции для работы с типизированным файлом
  1. Procedure AssignFile( f: File of Type; FileName: String);

    2. Связывает файловую переменную f с дисковым файлом FileName.

  2. Procedure Rewrite( f: File of Type);

    3. Создает новый файл и открывает его. Если файл существует, то он уничтожается и создается как новый.

  3. Procedure Reset( f: File of Type);

    4. Открывает существующий файл и устанавливает указатель на первую запись. При отсутствии файла возникает ошибка ввода/вывода.

  4. Procedure Read( f: File of Type[; v1, v2, …,vN]);

    5. Читает записи из файла и заносит их в переменные v1, v2, …, vN. Чтение начинается с той записи, на которую установлен указатель. Типы файла и переменных должны быть одинаковы.
  5. Procedure Write( f: File of Type[; v1, v2, …,vN]);

    6. Записывает данные из переменных v1, v2, …, vN в файл. Вывод данных начинается с той записи, на которую установлен указатель. Если указатель установлен на существующую запись, то при выводе она будет замещена новой записью. Если одновременно выводится несколько записей, то будет замещено такое же количество существующих записей. Типы файла и переменных должны быть одинаковы.

  6. Procedure Seek( f: File of Type; N: LongInt);

    7. Перемещает указатель на запись с номером N. Первая запись имеет порядковый номер 0.
  7. Function FilePos( f: File of Type): LongInt;

    8. Возвращает номер записи, на которую установлен указатель.
  8. Procedure CloseFile( f: File of Type);

    9. Закрывает файл.

  9. Function Eof(f: File of Type): boolean;

    10. Возвращает True, если достигнут конец файла.
  10. Function FileSize(f: File of Type): LongInt;

    11. Возвращает количество записей в файле. Например, Seek(f, FileSize(f)) установит указатель в конец файла (после последней записи).

  11. Procedure Truncate(f: File of Type);

    12. Уничтожает (отрубает) конец файла начиная с записи, на которую установлен указатель.

17.4. Файлы без типа

Файл состоит из компонент одинакового размера. Тип данных не имеет значения. Доступ к данным осуществляется через файловую переменную. Как и в файлах с типом, в таком файле допустим прямой доступ к любой записи, причем в рамках открытого файла допустимо как писать, так и читать записи.

Файловая переменная может быть объявлена так:

Var F: File;

После каждого чтения или вывода записи указатель автоматически устанавливается на следующую запись.

Отсутствие типа записи позволяет выполнять обработку файлов различных типов с помощью универсальных процедур и функций.

17.4.1. Процедуры и функции для работы с файлом без типа

  1. Procedure AssignFile( f: File; FileName: String);

    2. Связывает файловую переменную f с дисковым файлом FileName.

  2. Procedure Rewrite( f: File);

    3. Создает новый файл и открывает его. Если файл существует, то он уничтожается и создается как новый.

  3. Procedure Reset( f: File[; Size: Word]);

    4. Открывает существующий файл и устанавливает указатель на первую запись. При отсутствии файла возникает ошибка ввода/вывода. Параметр Size указывает размер записи открываемого файла. При его отсутствии размер записи по умолчанию равен 1.

  4. Procedure BlockRead( f: File; Var Buf; Count: Word[; Var Result: Word]);

    5. Читает из файла Count записей в переменную Buf. Result – реально прочитанное количество записей.

  5. Procedure BlockWrite( f: File; Var Buf; Count: Word[; Var Result: Word]);

    6. Пишет в файл первых Count записей из переменной Buf. Result – реально записанное количество записей.

  6. Procedure Seek( f: File; N: LongInt);

    7. Перемещает указатель на запись с номером N. Первая запись имеет порядковый номер 0.
  7. Function FilePos( f: File): LongInt;

    8. Возвращает номер записи, на которую установлен указатель.
  8. Procedure CloseFile( f: File);

    9. Закрывает файл.

  9. Function Eof(f: File): boolean;

    10. Возвращает True, если достигнут конец файла.
  10. Function FileSize(f: File): LongInt;

    11. Возвращает количество записей в файле. Например, Seek(f, FileSize(f)) установит указатель в конец файла (после последней записи).

  11. Procedure Truncate(f: File of Type);

Уничтожает (отрубает) конец файла начиная с записи, на которую установлен указатель.

Язык Object Pascal не накладывает никаких ограничений на длину записи (теоретически она может иметь размер до 2 Гб).

Пример описания и обращения к функции ReadFromFile, читающей из файла nF в позиции Pos запись r размером Sz.

function ReadFromFile(nF: String; Pos: Word; Var r; Sz: Word): boolean;

Var
g: File;
Recs, ReadReal: Integer;
RecRead: boolean;

Begin

Assign(g, nF);
Recs:= FileSize(g) div Sz; {количество записей в файле}
RecRead:= (Pos < Recs); {запись с номером Pos есть ?}
if RecRead then begin {если запись есть}
Reset(g, Sz); {открыть файл}

try

Seek(g, Pos); {установить указатель на запись}
BlockRead(g, r, 1, ReadReal); {прочитать запись}
RecRead:= (ReadReal = 1); {прочитано успешно ?}

finally
Close(g); {закрыть файл}
end;

end;
Result:= RecRead;

end {ReadFromFile};

…

Type

tStud = Record
Fio: String [60];
Curs: byte;
Stipendiya, Room: boolean;
End;

Var Stud: tStud;

…

if ReadFromFile('base2.ff1', 12, Stud, SizeOf(Stud))
then Writeln('Запись из 12-й позиции прочитана');

Приведем еще пример. В директории 'c:\Bases\SdudBase' находится файл 'AllStuds.bs', в котором хранятся данные о студентах в виде записей типа

Type

TStud = Record {студент}
Fio: String[50]; {'Фамилия Имя Отчество'}
Born: byte; {Год рождения, например, 1979}
Faculty: String[4]; {Факультет, например, 'МТФ'}
Group: String[8]; {Группа, например, 'МТ 17-2'}
End;

Ниже приведена универсальная процедура, которая копирует из этого файла в другой файл данные только о тех студентах, которые имеют заданный год рождения:

Procedure StudsCopy(nF1, nF2: ShortString; BornYear: byte;
Var Count: Word; Var: Ind: ShortInt);

{nF1 – файл-источник, nF2 – файл-приёмник,
BornYear – требуемый год рождения,
Count – скопировано записей,
Ind – индикатор контроля:
  0 – нормально, 1 – было неверное чтение, была неверная запись}

Var

g: tStud;
K, Sz, i,j: Word;
f1, f2: File;

Begin

Count:= 0; {инициализация счетчика}
Ind:=0; {изначально предполагаем нормальный процесс, иначе Ind изменим}
Sz:= SizeOf(g); {размер одной записи}
K:= KdnFileSize(nF1, Sz); {количество записей в файле-источнике}

If (K > 0) then {если в файле-источнике есть записи }
Begin
Assign(f1, nF1); {файл-источник связываем переменной f1}
Reset(f,Sz); {открываем файл-источник с записями размера Sz}
Assign(f2, nF2); {файл-приёмник связываем переменной f2 }
Rewrite(f2,Sz); {создаем новый файл-приёмник под записи размера Sz}

try

For j:=1 to K do
Begin
BlockRead(f1, g, 1, i); {чтение записи}

Case i of

1: {запись прочитана}
if (g.Born = BornYear) then { студент имеет требуемый год рождения}
begin
BlockWrite(f2, g, 1, i); {запись в файл-приёмник}
If (i > 0) then Inc(Count) {если записано правильно}
else
begin Ind:= 1; Break; End; {записано неверно, сразу выход из цикла}
end; {if}

0: begin Ind:= -1; Break; end; {запись не прочитана, сразу выход из цикла}
end; {Case}

end; {цикла For}

finally
CloseFile(f1); {закрываем файл-источник}
CloseFile(f2); {закрываем файл-приёмник}
end; {блока try – finally – end}

End {If };

End {StudsCopy};

Операторы, реализующие копирование требуемых данных в файл '1979.bs':

StudsCopy ('AllStuds.bs', '1979.bs', 1979, Count1979, Ind1979);

Case Ind1979 of
-1: Writeln('Зафиксирована ошибка чтения');
1: Writeln('Зафиксирована ошибка записи');
0: Writeln('Процесс прошел нормально');
end; {Case}

Writeln('Скопировано записей: ' + IntToStr(Count1979));

В этом примере использована внешняя процедура KdnFileSize {количество записей в файле }. Приведем ее текст:

function KdnFileSize(nF: ShortString, Siz: Word): LongInt;
{nF – имя файла, Siz – размер одной записи }

Var

F: File;
L: LongInt;

Begin
 L:=0;

If FileExists(nF) then
begin
Assign(f, nF);
Reset(f,1);
L:= SizeOf(f);
If not (L mod Siz = 0) then Writeln('Файл ' + nF + имеет другой тип');
L:= L div Siz;
CloseFile(f);
End;

Result:= L;
End;

17.5. Процедуры и функции для работы с файлами

Эти подпрограммы предназначены для работы с файлами, папками (директориями) и дисками.

  1. Procedure ChDir(Dir: String);

    2. Делает папку Dir текущей. Пример: ChDir('c:\');

  2. Procedure GetDir(D: Byte; Var Dir: String);

    3. Возвращает текущую папку на заданном устройстве. (D= 0 – текущий диск, 1 – диск А, 2 – диск B и т.д.). Пример: GetDir(0, s);

  3. Procedure RmDir(Dir: String);

    4. Уничтожает заданную папку. Папка не должна содержать вложенных папок или файлов. Пример: RmDir('Folder66');

  4. Procedure Erase(f);

    5. Удаляет файл, связанный с файловой переменной f. Файл должен быть закрыт.

  5. Procedure Rename(f, FileName: String);

    6. Переименовывает файл, связанный с файловой переменной f. Файл должен быть закрыт. Пример: Rename(g, 'studs.txt');

  6. Function DiskFree(D: byte): LongInt;

    7. Возвращает количество свободной памяти в байтах на устройстве D. Код драйвера задается так же, как в процедуре GetDir. Если код указан неверно, то возвращает -1.

  7. Function DiskSize(D: byte): LongInt;

    8. Возвращает количество свободной памяти в байтах на устройстве D. Код драйвера задается так же, как в процедуре GetDir. Если код указан неверно, то возвращает -1.

  8. Function FindFirst(const Path: string; Attr: Integer;
    var F: TSearchRec): Integer;

    9. Находит имя первого файла с заданными атрибутами Attr в папке Path. Результат поиска выводит в переменную F. Если поиск успешен, то функция вернет 0, иначе вернет код ошибки Widows. К FindFirst можно обращаться не только как к функции, но и как к процедуре.

Атрибуты файла приведены в табл. 17.

Таблица 17

    Атрибут

    Описание файлов

    faReadOnly

    faHidden

    faSysFile

    faVolumeID

    faDirectory

    faArchive

    faAnyFile

    Файлы "Только для чтения"

    Скрытые файлы

    Системные файлы

    Файл ID-значений

    Папки (директории)

    Архивы (файлы)

    Все файлы

    Тип, характеризующий найденный файл, представляет запись вида :

    type

    TSearchRec = Record
    Time: Integer; {время}
    Size: Integer; {размер файла в байтах}
    Attr: Integer; {атрибуты файла}
    Name: TFileName; {DOS-путь файла}
    ExcludeAttr: Integer;
    FindHandle: THandle;
    FindData: TWin32FindData; {дополнительная информация о файле}
    end;

    Пример:

    Var

    SR: TSearchRec;
    S: String;
    …
    FindFirst('c:\Program Files\delphi4\bin\*.*', faAnyFile, SR);
    if (SR.Attr = faArchive) then
    S:= 'Файл ' + SR.Name + ' имеет размер ' + IntToStr(SR.Size) + ' байт';

    В данном примере процедура FindFirst ищет первый файл по маске '*.*' (все файлы) в папке 'c:\Program Files\delphi4\bin'. Атрибут faAnyFile означает, что поиск производится по всем видам файлов, под которыми понимаются папки (директории), '.', '..' – ссылки на текущую и родительскую папку, внутренние папки и собственно файлы. Последние в терминологии файловой атрибутики называются архивами. Далее, если найденный файл есть архив, т е. файл в общепринятой терминологии, то в строку S будет помещено сообщение. Например, если найденный файл имеет имя Ig.ttg и его размер равен 15899, то S= 'Файл Ig.ttg имеет размер 15889 байтов'.

  1. Function FindNext(var F: TSearchRec): Integer;

    2. Находит следующий файл, атрибуты которого указаны в FindFirst.

  2. Procedure FindClose(var F: TSearchRec);

    3. Закрывает действие FindFirst/FindNext.

  3. Function DeleteFile(const FileName: string): Boolean;

    4. Удаляет файл по имени. Если файл не может быть удален или не существует – возвращает False.

  4. Function CreateDir(const Dir: string): Boolean;

    5. Создает новую папку.
  5. Function GetCurrentDir: string;

    6. Возвращает текущую папку.
  6. Function GetCurrentDir: string;

    7. Возвращает текущую папку.
  7. Function SetCurrentDir(const Dir: string): Boolean;

    8. Установка новой текущей папки.
  8. Function RemoveDir(const Dir: string): Boolean;

    9. Удаление папки. Перед удалением папка должна быть пустой.
  9. Function ExtractFileDir(const FileName: string): string;

    10. Выделяет из полного имени файла FileName папку, в которой содержится это файл.

  10. Function ExtractFilePath(const FileName: string): string;

    11. Выделяет из полного имени файла FileName путь до файла.

  11. Function ExtractFileExt(const FileName: string): string;

    12. Возвращает расширение файла FileName.

  12. Function ExtractFileName(const FileName: string): string;

    13. Возвращает имя файла FileName (без расширения).

  13. Function DirectoryExists(Dir: string): boolean;

    14. Проверяет существование директории. Пример:

    if DirectoryExists('C:\APPS\SALES\LOCAL') then ;

  14. Function FileExists(FileName: string): boolean;

    15. Проверяет существование файла. Примеры:

    B:= FileExists('C:\APPS\SALES\LOCAL\Fort.pas'); {полное имя}

    B:= FileExists('Fort.pas'); {указано усеченное имя файла, проверка его существования только в текущей директории}

  15. Procedure ForceDirectories(Dir: string);

    16. Создает новую директорию.

  16. Procedure ForceDirectories(C:\APPS\SALES\LOCAL).

П р и м е ч а н и е. К моменту обращения к процедуре директории APPS и SALES должны существовать.

Пример процедуры удаления данных из текущей директории, включая файлы и вложенные папки.

Procedure DelInsideDir(FullDir: tPathStr);
Var 
L: Integer; 
Sr: TSearchRec; 
dr, q: tPathStr;
begin 
if ExistDir(FullDir) then {такая директория есть}
begin
GetDir(0,dr); {запомнить текущую директорию}
ChDir(FullDir); {текущей становится удаляемая директория}
L:=FindFirst(Slash(FullDir)+'*.*',faAnyFile,Sr);{поиск первого файла}
try
While (L = 0) do begin {пока файлы находятся}
Case Sr.Attr of
faDirectory:{найденный файл – внутренняя директория}
if (Sr.Name<>'.') and (Sr.Name<>'..') then {это не ссылка, директория}
begin
{удаление внутреннего содержимого директории}
DelInsideDir(Slash(FullDir)+Sr.Name); 
q:= Slash(FullDir)+Sr.Name;
ChDir(ExtractFilePath(q));
{удаление самой директории (можно, т. к. она теперь пуста)}
if NotEmpStr(ExtractFileName(q)) then RmDir(ExtractFileName(q)); 
end;
faArchive: DeleteFile(Sr.Name); {это файл, удаляется}
end; {Конец Case-оператора}
L:= FindNext(Sr); {следующий файл директории}
end; {цикла While}
finally 
FindClose(Sr); {закрыть поиск файлов}
end; {try – finally – end}
ChDir(dr); {вернуться в текущую директорию}
end; {if}
end;{процедуры}

Например, если необходимо стереть данные с дискеты, то это можно сделать с помощью оператора: DelInsideDir('A:\');

 

 
</body> </html>